*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDD7N20
** 200V N-Channel MOSFET and D-PAK
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDD7N20 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 220
Lgate 1 9    1.183e-9
Ldrain 2 5   1.440e-9
Lsource 3 7  9.664e-10
RLgate 1 9   10
RLdrain 2 5  10
RLsource 3 7 10
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.34e-3 TC2=-1.34e-6)
.MODEL DbodyMOD D (IS=6.25e-10 N=1.5      RS=2.22e-2  TRS1=1.3e-3 TRS2=1.0e-6 
+ CJO=2.80e-10     M=0.49      VJ=0.45    TT=1.44e-7  XTI=3       EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1.0e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.544
.MODEL RdrainMOD RES (TC1=8.48e-3 TC2=1.96e-5)
M_BSIM3 16 6 7 7 Bsim3 W=0.502 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10   XJ=1.24e-7     NCH=1.76e17    
+ U0=700         VSAT=1.0e5     DROUT=1.0       
+ DELTA=0.1      PSCBE2=0       RSH=1.35e-3 
+ VTH0=4.07      VOFF=-0.1      NFACTOR=1.1     
+ LINT=4.26e-7   DLC=4.26e-7    FC=0.5
+ CGSO=1.01e-15  CGSL=0         CGDO=7.25e-12  
+ CGDL=4.32e-10  CJ=0           CF=0
+ CKAPPA=0.02    KT1=-2.04      KT2=0
+ UA1=-1.52e-9   NJ=10)
.ENDS
*$
*************** Power Discrete MOSFET Thermal Model ********************
** Package: D-PAK
**----------------------------------------------------------------------
.SUBCKT FDD7N20_Thermal TH TL
CTHERM1 TH 6 7.24e-4
CTHERM2 6 5  9.58e-4
CTHERM3 5 4  1.04e-3
CTHERM4 4 3  1.82e-3
CTHERM5 3 2  3.42e-3
CTHERM6 2 TL 2.02e-2
RTHERM1 TH 6 8.08e-4
RTHERM2 6 5  1.08e-3
RTHERM3 5 4  8.91e-2
RTHERM4 4 3  3.87e-1
RTHERM5 3 2  9.22e-1
RTHERM6 2 TL 1.50e+0
.ENDS FDD7N20_Thermal
**-------------------------------------------------------------------------------
** Creation: Jun.-15-2023   Rev.: 1.0
** onsemi
*$