*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDD6N50TM-F085
** 500V N-Channel MOSFET
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDD6N50 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 550
Lgate 1 9    1.12e-9
Ldrain 2 5   1.45e-9
Lsource 3 7  9.66e-10
RLgate 1 9   11.2
RLdrain 2 5  14.5
RLsource 3 7 9.6
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=9.08e-4 TC2=-1.08e-7)
.MODEL DbodyMOD D (IS=3.45e-13  N=1      RS=1.16e-2  TRS1=2.52e-2  TRS2=1e-5 
+ CJO=1.82e-9      M=0.76       VJ=0.46  TT=2.12e-7  XTI=3         EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1.0e-6)
Rdrain 5 16 RdrainMOD 0.75
.MODEL RdrainMOD RES (TC1=7.22e-3 TC2=2.15e-5)
M_BSIM3 16 6 7 7 Bsim3 W=2.68 L=2.0e-6 NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10    XJ=1.4e-6     NCH=1.64e17
+ U0=600          VSAT=1.0e5    DROUT=10.0
+ DELTA=0.1       PSCBE2=0      RSH=4.62e-3 
+ VTH0=4.25       VOFF=-0.1     NFACTOR=1.1
+ LINT=5.42e-7    DLC=5.42e-7   FC=0.5
+ CGSO=1.05e-15   CGSL=1.0e-15  CGDO=1.0e-14
+ CGDL=2.65e-10   CJ=0          CF=0   
+ CKAPPA=0.018    KT1=-1.88     KT2=0
+ UA1=3.0e-9      NJ=10)
.ENDS
*$
*************** Power Discrete MOSFET Thermal Model ********************
** Package: D-PAK
**----------------------------------------------------------------------
.SUBCKT FDD6N50_Thermal TH TL
CTHERM1 TH 6 5.04e-5
CTHERM2 6 5  9.68e-4
CTHERM3 5 4  5.24e-3
CTHERM4 4 3  2.52e-2
CTHERM5 3 2  8.82e-2
CTHERM6 2 TL 1.42e-1
RTHERM1 TH 6 4.38e-3
RTHERM2 6 5  1.88e-2
RTHERM3 5 4  8.58e-2
RTHERM4 4 3  1.07e-1
RTHERM5 3 2  3.51e-1
RTHERM6 2 TL 8.33e-1
.ENDS FDD6N50_Thermal
**---------------------------------------------------------------------
** Creation: Jun.-15-2018   Rev.:1.0
** ON Semiconductor
*$