*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDD18N20LZ 
** N-Channel UniFET MOSFET
** 200V, 16A, 125mohm
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDD18N20LZ 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 220
Lgate 1 9    3.626e-9
Ldrain 2 5   2.291e-10
Lsource 3 7  1.892e-9
RLgate 1 9   10
RLdrain 2 5  10
RLsource 3 7 10
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.34e-3 TC2=-1.15e-6)
.MODEL DbodyMOD D (IS=1.15e-12  N=1.0     RS=8.64e-3   TRS1=2.35e-3   TRS2=6.85e-6 
+ CJO=1.16e-9      M=0.55       VJ=0.66   TT=1.15e-7   XTI=3          EG=1.16)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1.0e-3 TRS2=5.0e-6)
Rdrain 5 16 RdrainMOD 0.10
.MODEL RdrainMOD RES (TC1=7.88e-3 TC2=2.29e-5)
Desd 7 9 DesdMOD
.MODEL DesdMOD D (IS=1.0e-15  N=1  IBV=5.0e-4  BV=20)
M_BSIM3 16 6 7 7 Bsim3 W=2.366 L=2.00e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=580e-10     XJ=1.04e-6      NCH=1.74e17
+ U0=700          VSAT=1.0e5     DROUT=10.0
+ DELTA=0.1       PSCBE2=0       RSH=3.19e-4
+ VTH0=1.65       VOFF=-0.1      NFACTOR=1.1
+ LINT=5.45e-7    DLC=5.45e-7    
+ CGSO=1.05e-15   CGSL=0         CGDO=5.05e-15  
+ CGDL=5.28e-10   CJ=0           CF=0
+ CKAPPA=0.08     KT1=-0.97      KT2=0
+ UA1=1.05e-9     NJ=10)
.ENDS
*$
******************** Power Discrete MOSFET Thermal Model ************************
** 200V N-Channel MOSFET and D-PAK
**-------------------------------------------------------------------------------
.SUBCKT FDD18N20LZ_Thermal TH TL
CTHERM1 TH 6 4.04e-4
CTHERM2 6 5  9.84e-4
CTHERM3 5 4  4.72e-3
CTHERM4 4 3  6.64e-3
CTHERM5 3 2  7.12e-3
CTHERM6 2 TL 8.02e-3
RTHERM1 TH 6 1.50e-3
RTHERM2 6 5  3.40e-2
RTHERM3 5 4  7.80e-2
RTHERM4 4 3  2.29e-1
RTHERM5 3 2  4.91e-1
RTHERM6 2 TL 5.66e-1
.ENDS FDD18N20LZ_Thermal
**-------------------------------------------------------------------------------
** Creation: Jul.-01-2022   Rev.: 1.0
** onsemi
*$