*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDD1600N10ALZ 
** 100V N-Channel Power Trench MOSFET
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDD1600N10ALZ 2 1 3    
**Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 110
Lgate 1 9    1.12e-9
Ldrain 2 5   1.45e-9
Lsource 3 7  9.66e-10
RLgate 1 9   11.2
RLdrain 2 5  14.5
RLsource 3 7 9.6
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7.46e-4 TC2=-1.15e-6)
.MODEL DbodyMOD D (IS=6.05e-14  N=1      RS=2.06e-2  TRS1=1.30e-3 TRS2=1.38e-5 
+ CJO=1.38e-10     M=0.14       VJ=0.57  TT=3.55e-8  XTI=3         EG=1.12)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1.0e-6)
Rdrain 5 16 RdrainMOD 0.124
.MODEL RdrainMOD RES (TC1=6.23e-3 TC2=1.05e-7)
M_BSIM3 16 6 7 7 Bsim3 W=0.458 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10    XJ=1.4e-6      NCH=9.24e16
+ U0=700          VSAT=5.0e5     DROUT=1.0
+ DELTA=0.10      PSCBE2=0       RSH=3.09e-3 
+ VTH0=1.95       VOFF=-0.1      NFACTOR=1.1
+ LINT=3.98e-7    DLC=3.98e-7    FC=0.5
+ CGSO=1.05e-14   CGSL=1.0e-15   CGDO=1.05e-11
+ CGDL=1.88e-10   CJ=0           CF=0   
+ CKAPPA=0.2      KT1=-1.45      KT2=0
+ UA1=2.0e-9      NJ=10)
.ENDS
*$
******************** Power Discrete MOSFET Thermal Model ************************
** 100V N-Channel MOSFET and D-PAK
**-------------------------------------------------------------------------------
.SUBCKT FDD1600N10ALZ_Thermal TH TL
CTHERM1 TH 6 1.04e-5
CTHERM2 6 5  1.08e-4
CTHERM3 5 4  4.64e-4
CTHERM4 4 3  7.02e-4
CTHERM5 3 2  1.02e-3
CTHERM6 2 TL 2.16e-3
RTHERM1 TH 6 1.20e-1
RTHERM2 6 5  7.20e-1
RTHERM3 5 4  8.85e-1
RTHERM4 4 3  9.05e-1
RTHERM5 3 2  1.28e+0
RTHERM6 2 TL 4.49e+0
.ENDS FDD1600N10ALZ_Thermal 
**-------------------------------------------------------------------------------
** Creation: Apr.-22-2014   Rev: 0.0
** Fairchild Semiconductor
*$