.SUBCKT FDC5661N 2 1 3
******************************************************************
**	Fairchild Discrete Modeling Group			**
******************************************************************
**	Website		www.fairchildsemi.com\models		**
**	Scott Pearson	scott.pearson@fairchildsemi.com		**
**	Sylvie Tran	sylvie.tran@fairchildsemi.com		**
******************************************************************
**	(C) Copyright 2008 Fairchild Semiconductor Corporation	**
**			All rights reserved			**
**								**
**			FDC5661N Spice model			**
**			Revision RevA, 12 Jan 2009		**
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.559e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.196e-9
RLgate 1 9 5.59
RLdrain 2 5 1
RLsource 3 7 1.96
Rgate 9 6 2.1
It 7 17 1
Ebreak 11 7 17 7 67.5
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=0.5e-12 n=1 RS=10e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=1.2e-10 M=0.4 TT=2e-9 XTI=3)
.MODEL DbreakMOD D (RS=20e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 3.8e-3
Rdrain 5 16 RdrainMOD 31.1e-3
.MODEL RdrainMOD RES (TC1=6.2e-3 TC2=1.1e-5)
M_BSIM3 16 6 7a 7a Bsim3 W=1.09 L=1.58e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.91e-6 ;Channel depth
+ NCH=1.1e17 ;Channel concentration
*Channel Current
+ U0=950 VSAT=800000 DROUT=1.8
+ DELTA=0.05 PSCBE2=0.00001 RSH=3.911e-3
*Threshold voltage
+ VTH0=2.34
*Sub-threshold characteristics
+ VOFF=-0.21 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.31e-6 DLC=0.31e-6
+ CGSO=124e-12 CGSL=0 CGDO=0.5e-12 CGDL=275e-12
+ CJ=0 CF=0 CKAPPA=1.5
* Temperature parameters
+ KT1=-1.02 KT2=0 UA1=3.7e-9
+ NJ=10)
* RevA	SP	1/8/2009
.ENDS