.SUBCKT FDB86102LZ 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDB86102LZ Spice model                  **
**                      Revision RevA, 12 April 2011            **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 5.452e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 3.015e-9
RLgate 1 9 54.52
RLdrain 2 5 1
RLsource 3 7 30.15
Rgate 9 6 0.37
* Shielded  Gate
D_D1 100 5 D_SG_cap1
D_D2 100 101 D_SG_cap2
R_R1 101 7 0.29
C_C1 6 101 39e-12
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=1.3e-9 M=0.6 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=1.1e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 109.4
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.68e-3 TC2=-0.6e-6)
.MODEL DbodyMOD D (IS=4e-12 n=1 RS=4.9e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=0.26e-9 M=0.40 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=2e-6 )
Rsource 7a 7 0.256e-3
Rdrain 5 16 RdrainMOD 15.2e-3
.MODEL RdrainMOD RES (TC1=6.2e-3 TC2=18e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=1.68 L=1.226e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=550e-10
+ XJ=0.62e-6
+ NCH=1.0e17
*Channel Current
+ U0=950 VSAT=500000 DROUT=1.8
+ DELTA=0.3 PSCBE2=0 RSH=0.256e-3
*Threshold voltage
+ VTH0=1.75
*Sub-threshold characteristics
+ VOFF=-0.21 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.141e-6 DLC=0.141e-6
+ CGSO=88e-12 CGSL=0 CGDO=1e-12 CGDL=165e-12
+ CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-1.03 KT2=0 UA1=4e-9
+ NJ=10)
.ENDS

.SUBCKT FDB86102LZ_JC TH TL
*Thermal Model Subcircuit  10/23/2013
*Foster thermal model
CTHERM1 th 6 1.2e-3 	   
CTHERM2 6 5 2.3e-3
CTHERM3 5 4 3.5e-3
CTHERM4 4 3 6.0e-3
CTHERM5 3 2 1.0e-2
CTHERM6 2 tl 6.0e-2
RTHERM1 th 6 .02
RTHERM2 6 5 .1
RTHERM3 5 4 .2
RTHERM4 4 3 0.3
RTHERM5 3 2 0.45
RTHERM6 2 tl 0.55
.ends

.SUBCKT FDB86102LZ_JC_cauer TH TL
*Cauer thermal model
ctherm1 th 0 5.443e-4
ctherm2 2 0 5.796e-4
ctherm3 3 0 1.893e-3
ctherm4 4 0 5.822e-3
ctherm5 5 0 0.022
ctherm6 6 0 0.066
rtherm1 th 2 0.091
rtherm2 2 3 0.373
rtherm3 3 4 0.377
rtherm4 4 5 0.284
rtherm5 5 6 0.178
rtherm6 6 0 0.317
.ends