**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDB44N25
** 330V N-Channel MOSFET and D2-PAK
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDB44N25 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 250
Lgate 1 9    4.989e-9
Ldrain 2 5   1.44e-9
Lsource 3 7  2.49e-9
RLgate 1 9   49.89
RLdrain 2 5  14.4
RLsource 3 7 14.9
Rgate 9 6    1.4
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1e-3 TC2=-0.9e-6)
.MODEL DbodyMOD D (IS=3.05e-11 n=1 RS=7.42e-3 TRS1=2.5e-3 TRS2=1e-6 
+ CJO=3.74e-9 M=0.48 VJ=0.47 TT=10.5n XTI=3 EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 3.88e-2
.MODEL RdrainMOD RES (TC1=1.2e-2 TC2=6.1e-5)
M_BSIM3 16 6 7 7 Bsim3 W=4.0 L=2.0u NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10 XJ=1.4u    NCH=1.3e17
+ U0=700       VSAT=5.5e5 DROUT=1.0
+ DELTA=0.10   PSCBE2=0   RSH=7.09e-4
+ VTH0=4.62    VOFF=-0.1  NFACTOR=1.1
+ LINT=0.18u   DLC=0.18u  FC=0.5
+ CGSO=8.2e-12 CGSL=0     CGDO=8.0e-12 CGDL=740p
+ CJ=0         CF=0       CKAPPA=0.00028
+ KT1=-2.58    KT2=0      UA1=2e-9
+ NJ=10
.ENDS FDB44N25

*************** Power Discrete MOSFET Thermal Model ********************
** Product: FDB44N25
**----------------------------------------------------------------------
.SUBCKT FDB44N25_THERMAL TH TL
CTHERM1 TH 6 1.04e-5
CTHERM2 6 5  2.08e-3
CTHERM3 5 4  1.64e-2
CTHERM4 4 3  2.92e-2
CTHERM5 3 2  3.62e-1
CTHERM6 2 TL 4.82e-1
RTHERM1 TH 6 9.7e-4
RTHERM2 6 5  8.7e-3
RTHERM3 5 4  9.7e-3
RTHERM4 4 3  7.5e-2
RTHERM5 3 2  8.6e-2
RTHERM6 2 TL 2.3e-1
.ENDS FDB44N25_THERMAL
**---------------------------------------------------------------------
** Creation: Jan.-30-2008   Rev.:0.0
** Fairchild Semiconductor