**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDB075N15
** 150V N-Channel Power Trench MOSFET
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDB075N15A 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 150
Lgate 1 9    1.183e-9
Ldrain 2 5   1.440e-9
Lsource 3 7  1.012e-9
RLgate 1 9   11.83
RLdrain 2 5  14.40
RLsource 3 7 10.12
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8.14e-4 TC2=-1.54e-6)
.MODEL DbodyMOD D (IS=6.25e-12   N=1      RS=1.47e-3    TRS1=2.98e-3   TRS2=3.05e-6 
+ CJO=4.52e-9      M=0.58        VJ=0.47  TT=8.188e-8   XTI=3          EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.005625
.MODEL RdrainMOD RES (TC1=8.79e-3 TC2=3.08e-5)
M_BSIM3 16 6 7 7 BSIM3 W=9.387 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1000e-10     XJ=1.1e-6      NCH=1.3e16
+ U0=700           VSAT=5.5e5     DROUT=1.0
+ DELTA=0.1        PSCBE2=0       RSH=1.29e-4
+ VTH0=3.70        VOFF=-0.1      NFACTOR=1.1
+ LINT=2.71e-7     DLC=2.71e-7    FC=0.5
+ CGSO=1.2e-15     CGSL=0         CGDO=1.50e-14
+ CGDL=3.05e-10    CJ=0           CF=0 
+ CKAPPA=0.2       KT1=-1.74      KT2=0
+ UA1=-1.9e-9      NJ=10)
.ENDS

*************** Power Discrete MOSFET Thermal Model ********************
** Package: D2-PAK
**----------------------------------------------------------------------
.SUBCKT FDB075N15A_THERMAL TH TL
CTHERM1 TH 6 1.04e-5
CTHERM2 6 5  6.14e-4
CTHERM3 5 4  6.82e-3
CTHERM4 4 3  9.44e-3
CTHERM5 3 2  6.02e-2
CTHERM6 2 TL 2.02e-1
RTHERM1 TH 6 1.00e-4
RTHERM2 6 5  3.00e-3
RTHERM3 5 4  3.50e-2
RTHERM4 4 3  9.60e-2
RTHERM5 3 2  1.050E-01
RTHERM6 2 TL 2.110E-01
.ENDS FDB075N15A_THERMAL
**-------------------------------------------------------------------------
** Creation: Jun.-02-2011   Rev.: 0.0
** Fairchild Semiconductor