**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product: FCPF20N60
** Package: TO-220F
** 600V N-Channel MOSFET
**-------------------------------------------------------------------------------
.SUBCKT FCPF20N60 20 10 30
Rg 10 1 1.58
M1 2 1 3 3 DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO={4.75*{-0.001*TEMP+1.025}} KP={-0.0096*TEMP+20}
+ THETA=0.0416   VMAX=1.0E5   LEVEL=3)
Cgs 1 3 2285p
Rd 20 4 0.07 TC=0.01
Dds 3 4 DDS
.MODEL DDS D(BV={700*{0.000975*TEMP+0.975625}}  M=0.48  CJO=9085p  VJ=0.34)
Dbody 3 20 DBODY
.MODEL DBODY D(IS=2.0E-12  N=1.00  RS=0.0084  EG=1.13  TT=530n)
Ra 4 2 0.07 TC=0.01
Rs 3 5 0.001
Ls 5 30 1.0n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS (VTO=0 KP=10 LEVEL=1)
CGDmax 7 4 4820p
Rcgd 7 4 1E7
Dgd 6 4 DGD
Rdgd 4 6 1E7
.MODEL DGD D(M=0.56 CJO=4820p VJ=0.0102)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
.ENDS
*********************** Power Discrete MOSFET Thermal Model *********************
.SUBCKT FCPF20N60_Thermal TH TL
CTHERM1 TH 6 2.04e-4
CTHERM2 6 5  2.28e-2
CTHERM3 5 4  2.34e-2
CTHERM4 4 3  3.62e-2
CTHERM5 3 2  4.62e-1
CTHERM6 2 TL 5.62e-1

RTHERM1 TH 6 1.320e-02
RTHERM2 6 5  2.770e-02
RTHERM3 5 4  4.620e-02
RTHERM4 4 3  7.060e-01
RTHERM5 3 2  8.050e-01
RTHERM6 2 TL 1.602e+00
.ENDS
**-------------------------------------------------------------------------------
** Creation: May-31-2007
** Fairchild Semiconductor