**************** Power Discrete MOSFET Electrical Circuit Model ****************
* Product Name: FCP11N60
* 600V N-Channel MOSFET and TO-220
*-------------------------------------------------------------------------------
.SUBCKT FCP11N60 20 10 30
Rg 10 1 1.58
M1 2 1 3 3 DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO={4.88*{-0.00016*TEMP+1.004}} KP={{0.00012*TEMP}+9.7}
+ THETA=0.0416  VMAX=1.0E5  LEVEL=3)
Cgs 1 3 1088p
Rd 20 4 0.15 TC=0.0105
Dds 3 4 DDS
.MODEL DDS D(BV={600*{0.001*TEMP+0.975}}  M=0.48   CJO=3988p   VJ=0.48)
Dbody 3 20 DBODY
.MODEL DBODY D(IS=2.0E-12  N=1.00  RS=0.018  EG=1.12  TT=200n)
Ra 4 2 0.15 TC=0.0105
Rs 3 5 0.0012
Ls 5 30 2.0n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS (VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 1448p
Rcgd 7 4 1E7
Dgd 6 4 DGD
Rdgd 4 6 1E7
.MODEL DGD D(M=0.58 CJO=1448p VJ=0.40)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
.ENDS

*------------------------------------------------------------------------------
******************** Power Discrete MOSFET Thermal Model **********************
.SUBCKT FCP11N60_Thermal TH TL
CTHERM1 TH 6 9.04e-4
CTHERM2 6 5  5.64e-3
CTHERM3 5 4  2.42e-2
CTHERM4 4 3  3.94e-2
CTHERM5 3 2  4.02e-1
CTHERM6 2 TL 5.02e-1
RTHERM1 TH 6 6.48e-3
RTHERM2 6 5  2.91e-2
RTHERM3 5 4  5.02e-2
RTHERM4 4 3  2.03e-1
RTHERM5 3 2  2.17e-1
RTHERM6 2 TL 4.95e-1
.ENDS
*------------------------------------------------------------------------------
* Creation: Nov-06-2007  Rev: 2.0
* Fairchild Semiconductor