*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FCA16N60N
** 600V N-Channel SupreMOS and TO-3PN
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FCA16N60N 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 660
Lgate 1 9    1.183e-9
Ldrain 2 5   1.183e-9
Lsource 3 7  1.658e-9
RLgate 1 9   11.83
RLdrain 2 5  11.83
RLsource 3 7 16.58
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.15e-3 TC2=-1.55e-6)
.MODEL DbodyMOD D (IS=6.0e-13  N=1.0    RS=6.32e-3   TRS1=2.32e-3  TRS2=5.2e-6 
+ CJO=7.06e-9      M=0.76      VJ=0.78  TT=3.15e-7   XTI=3         EG=1.12)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1.0e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.17
.MODEL RdrainMOD RES (TC1=8.85e-3 TC2=2.85e-5)
M_BSIM3 16 6 7 7 Bsim3 W=3.17 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1000e-10    XJ=1.4e-6      NCH=1.3e17
+ U0=700          VSAT=1.5e5     DROUT=1.0
+ DELTA=0.1       PSCBE2=0       RSH=1.1e-3
+ VTH0=2.95       VOFF=-0.1      NFACTOR=1.1
+ LINT=1.2e-7     DLC=1.2e-7     FC=0.5
+ CGSO=1.8e-15    CGSL=0         CGDO=5.06e-14
+ CGDL=3.68e-10   CJ=0           CF=0
+ CKAPPA=0.2      KT1=-1.37      KT2=0
+ UA1=-2.15e-9    NJ=10)
.ENDS
*$
******************** Power Discrete MOSFET Thermal Model ************************
** Package: TO-3PN
**-------------------------------------------------------------------------------
.SUBCKT FCA16N60N_Thermal TH TL
CTHERM1 TH 6 1.04e-4
CTHERM2 6 5  2.08e-3
CTHERM3 5 4  4.04e-3
CTHERM4 4 3  6.62e-3
CTHERM5 3 2  7.22e-3
CTHERM6 2 TL 1.02e-2
RTHERM1 TH 6 3.60e-3
RTHERM2 6 5  1.40e-2
RTHERM3 5 4  4.20e-2
RTHERM4 4 3  6.70e-2
RTHERM5 3 2  8.10e-2
RTHERM6 2 TL 7.22e-1
.ENDS FCA16N60N_Thermal 
**-------------------------------------------------------------------------------
** Creation: Sep.-02-2015   Rev.: 0.0
** Fairchild Semiconductor
*$