.SUBCKT CM2030 5V_SUPPLY TMDS_D2+ TMDS_D2- 0

 

 

 

***********************************

 **** 0 is gnd ****

************************************

 

************************************

**** Diode connected to 5V_SUPPLY  ****

************************************

 

Q_Q0  N_0002  N_0002 5V_SUPPLY pnpv  

 

**********************************************************************

**** Diode pair for TMDS_D2+ **** 

********************************************************************** 

 

************************************

**** ESD diode on Vdd side **** 

************************************

 

Q_Q1 0  N_0002 TMDS_D2+  pnpv 5  

 

************************************ 

**** ESD diode on Gnd side ****

************************************

 

Q_Q2 0 0 TMDS_D2+ npnL 1  

 

************************************ 

**** Parsitic cap to gnd ****

************************************       

 

C_C11 TMDS_D2+ 0 0.25e-12            

 

*************************************************************************

**** Diode pair for TMDS_D2- **** 

************************************************************************* 

 

************************************

**** ESD diode on Vdd side **** 

************************************

 

Q_Q3 0  N_0002 TMDS_D2-  pnpv 5  

 

************************************ 

**** ESD diode on Gnd side ****

************************************

 

Q_Q4 0 0 TMDS_D2- npnL 1  

 

************************************ 

**** Parsitic cap to gnd ****

************************************       

 

C_C12 TMDS_D2- 0 0.25e-12                  

 

************************************************************************** 

**** ESD zener diode ****

************************************************************************** 

D_D1  0  N_0002 zener 220        

 

 

.ENDS CM2030

 

 

 

*************************************************

** Lateral NPN Bipolar Devices

*************************************************

.MODEL NPNL NPN

+ IS=100E-18            

+ BF=40                 

+ VAF=40          

+ NF=1.04         BR=0.45

+ NR=1            ISE=100E-18 NE=1.5      

+ ISC=170E-18     NC=1.2            

+ VAR=50    IKF=200u    IKR=10

+ RB=500    RBM=1.2           IRB=4.0u

+ RE=15     RC=15       CJE=7.2fF

+ VJE=0.765 MJE=0.309   FC=0.5

+ CJC=30fF  VJC=0.774   MJC=0.342

+ TF=2ns    XTF=1       ITF=5.3214E-3

+ VTF=0.1124      PTF=22.23   TR=4.4356E-8

+ XTB=1.0034      EG=1.16           XTI=5 

*

*

*************************************************

** Vertical PNP Bipolar Devices

*************************************************

.MODEL PNPV PNP

+ IS=250E-18            

+ BF=40           

+ VAF=40          

+ ISE=200E-18

+ NF=1.4          BR=0.45

+ NR=1            NE=2.0      

+ ISC=200E-18     NC=1.2            

+ VAR=5           IKF=200u    IKR=10

+ RB=500    RBM=1.2           IRB=4.0u

+ RE=15     RC=60.345   CJE=200.852fF

+ VJE=0.765 MJE=0.209   FC=0.5

+ CJC=58fF  VJC=0.774   MJC=0.342

+ TF=2ns    XTF=1       ITF=5.3214E-3

+ VTF=0.1124      PTF=22.23   TR=4.4356E-8

+ XTB=1.0034      EG=1.16           XTI=5

 

 

*************************************************

 

** Zener Diodes

*************************************************

.MODEL ZENER D

+ IS=4E-13              

+ IKF=100mA             

+ RS= 0.1         

+ BV= 7.57              

+ ISR=1000E-18          

+ IBV=100E-6            IBVL=1E-6

+ NBV=2.0        NBVL=0.9

+ N=1.0                 NR=1.0

+ VJ=0.592        M=0.33                  FC=0.5

+ EG= 1.1         XTI=3

+ CJO=330E-15           

***************************