*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: BSS123LT1G 
** Power MOSFET 170 mAmps, 100 Volts, N-Channel
** Package: SOT-23
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT BSS123LT1G 1 2 3
M_BSIM3 9 7 8 8 Bsim3 W=0.0505 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=800e-10     XJ=1.4e-6      NCH=1.13e17
+ U0=700          VSAT=1.0e5     DROUT=1.0 
+ DELTA=0.1       PSCBE2=0       RSH=2.09e-2
+ VTH0=1.80       VOFF=-0.1      NFACTOR=1.1
+ LINT=5.38e-7    DLC=5.38e-7    FC=0.5
+ CGSO=1.0e-15    CGSL=0         CGDO=1.05e-14
+ CGDL=0          CJ=0           CF=0
+ CKAPPA=0.2      KT1=-1.37      KT2=0
+ UA1=2.05e-8     NJ=10)
RS 8 3 1.234
D1 3 1 MD
.MODEL MD D (IS=1.997e-13    RS=0.199485     N=1.0
+ EG=1.12    XTI=3           CJO=1.688e-11   VJ=0.75
+ M=0.40     TT=0            FC=0.5)
RDS 3 1 5e+10
RD 9 1 RdrainMOD 1.2706
.MODEL RdrainMOD RES (TC1=7.86e-3 TC2=2.32e-5)
RG 2 7 1
D2 4 5 MD1
.MODEL MD1 D (IS=1e-32 N=50
+ CJO=3.0255e-11    VJ=0.5    M=0.59    FC=0.5)
D3 0 5 MD2
.MODEL MD2 D (IS=1e-10   N=0.4    RS=3.003e-06)
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 7.4235e-10
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
.MODEL MD3 D IS=1e-10 N=0.4
Dbreak 9 16  DbreakMOD
Ebreak 16 8 17 8 130
It 8 17 1
Rbreak 17 8  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.1e-3 TC2=-1.05e-6)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1.0e-3 TRS2=1e-6)
.ENDS
**-------------------------------------------------------------------------------
** Creation: Aug.-26-2021   Rev.: 3.0
** ON Semiconductor
*$