* PIR EVB circuit
* NCS36000 is represented by 2 opamps (OA1_NCS36000 & OA2_NCS36000)
V1 1 0  AC 1 0
X1 1 2 4 OA1_NCS36000
X2 7 6 8 OA2_NCS36000
R1 3 0 {R}
C1 2 3 33UF
R2 2 4 560K
C2 2 4 10NF
R3 4 5 10K
C3 5 6 33UF
R4 6 8 1MEG
C4 6 8 10NF
V2 7 0 2.1
.param R=10k
.step param R list 1k 10k 20k 50k
.AC DEC 1k 100m 100
.print ac v(8)
.ENDS PIR_EVB

* OPAMP MACRO MODEL 1ST STAGE AMP FROM NCS36000, SINGLE-POLE
* connections:      	non-inverting input
*                   	|   inverting input
*                   	|   |   output
*                   	|   |   |
.SUBCKT OA1_NCS36000    1   2   6
* INPUT IMPEDANCE
RIN	1 2	10MEG
* DC-Gain=80dB=10k and Unity-Gain-BW=25kHz
* Choose RP1=1k
* <=> Fpole1 = Fu/Aol = 25kHz/10k = 2.5Hz
* <=> CP1 = 1/2*pi*RP1*Fpole1 = 63.6uF
EGAIN	3 0	1 2	10K
RP1	3	4	1K
CP1	4	0	63.6UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS

* OPAMP MACRO MODEL 2ND STAGE AMP FROM NCS36000, SINGLE-POLE
* connections:      	non-inverting input
*                   	|   inverting input
*                   	|   |   output
*                   	|   |   |
.SUBCKT OA2_NCS36000    1   2   6
* INPUT IMPEDANCE
RIN	1 2	10MEG
* DC-Gain=100dB=50k and Unity-Gain-BW=115kHz
* Choose RP1=1k
* <=> Fpole1 = Fu/Aol = 115kHz/50k = 2.3Hz
* <=> CP1 = 1/2*pi*RP1*Fpole1 = 72.3uF
EGAIN	3 0	1 2	50K
RP1	3	4	1K
CP1	4	0	72.3UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS