*	CAT5114 SPICE Macromodel
*	DESCRIPTION : 32 TAPS 50k DPP

* 	Digital control bits:	L1-d[0],L2-d[1],L3-d[2],L4-d[3],L5-d[4]
* 	DPP terminals:	H,W,L

******************************************************************
.subckt cat5114_50k   L1 L2 L3 L4 L5 H W L
*--------------------------------------------------------------------
* params
.param R0 	= 50000
.param N 	= 31
.param gi	= N/R0
.param rh	= 10
.param rl	= 10
.param rw	= 100
.param cw	= 10p
.param NH	= rh*gi+N
.param NL	= -rl*gi
*
* devices
*
Rh 	H 	1 	rh
Rw 	W 	2 	rw
Rl 	L 	3 	rl
Cw	w	0	cw
R1	11	12	1
R2	21	22	1
*
* independent voltage sources 
*
v1 	4 	0 	dc 	NH
v2 	5 	0 	dc 	NL
V3	11	0	dc	1V
V4	21	0	dc	1v
*
* VCVS - polynomial
*
ek 	6 	0 	poly(5) (L5,0) (L4,0) (L3,0) (L2,0) (L1,0) 0 16 8 4 2 1
e13 	13	0	poly(1) (4,6) 0 1
e23 	23	0	poly(1) (6,5) 0 1
*
* VCCS - polynomial
*
g12	12	0	poly(2) (12,0) 	(13,11)	0 0 0 0 1	
g22	22	0	poly(2) (22,0) 	(23,21)	0 0 0 0 1	
gh 	1 	2 	poly(2) (H,2) 	(12,0) 	0 0 0 0 gi
gl 	2 	3 	poly(2) (2,L) 	(22,0) 	0 0 0 0 gi
*
rx1 L1 0 10G
rx2 L2 0 10G
rx3 L3 0 10G
rx4 L4 0 10G
rx5 L5 0 10G
rx6 H 0 10G
rx7 W 0 10G
rx8 L 0 10G
rx10 1 0 10G
rx12 2 0 10G
rx13 3 0 10G
rx14 4 0 10G
rx15 5 0 10G
rx16 6 0 10G
rx21 11 0 10G
rx22 12 0 10G
rx23 13 0 10G
rx24 21 0 10G
rx25 22 0 10G
rx26 23 0 10G
*
.ends
******************************************************************