****************************** IGBT Electrical Parameters ***************************
** Product: FGB40N60SM
** 600V, 40A Field Stop IGBT
** Model Format: SPICE2G6
**-----------------------------------------------------------------------------------
** Simulator: SIMetrix 7.2
**-----------------------------------------------------------------------------------
.SUBCKT FGB40N60SM C G E
*#ASSOC Category=IGBT Symbol=FGB40N60SM
*
LE   74 E  1.658n 
RE   83 74 1.28e-3 TC=3.05e-3
RC   85 C  9.10e-3 TC=4.1e-3
RG   G 82  1.25
CGC  82 C  1p 
CGD  92 93 5.06n 
CGE  E 82  1830p
M1   81 82 83 83 MOS W=1u L=1u          
Q1   83 81 85 VPNP 
R1   92 0 1
R2   91 94 1
RLV  95 0 1
DBE  85 81 DE 
DSD  83 81 DO 
DHV  94 93 DR
DLV  94 95 DR 56
D1   91 92 DLIM 
D2   94 0 DLIM 
FFB  82 81 VFB 1
VFB  93 0 DC 0  
ESD  96 93 POLY(1) 83 81 19 1
MLV  95 96 93 93 SW           
EGD  91 0 82 81 1
.MODEL SW NMOS
+ LEVEL=3         VTO=0           KP=5
.MODEL VPNP PNP 
+ IS=8.05e-11     NF=1.5          BF=0.1241       CJE=8.0e-9
+ TF=1.09e-9      XTB=4.44        EG=1.16       
.MODEL MOS NMOS 
+ LEVEL=3         VMAX=2.0e5      THETA=0.064     ETA=2e-3
+ VTO=5.75        KP=25.8
.MODEL DR D
+ IS=1.0e-14      CJO=1.0e-10     M=0.84          VJ=0.46     
.MODEL DO D 
+ IS=1.0e-14      BV=660          CJO=2.0e-9      M=0.58
+ VJ=0.54    
.MODEL DE D
+ IS=1.0e-14      BV=30.0         N=2
.MODEL DLIM D 
+ IS=1.00e-7
*
.ENDS FGB40N60SM

******************************* IGBT Thermal Parameters ****************************
** Package: TO-263AB/D2-PAK
**----------------------------------------------------------------------------------
.SUBCKT FGB40N60SM_Thermal TH TL
*#ASSOC Category=IGBT Symbol=FGB40N60SM
*
CTHERM1 TH 6 6.40e-5
CTHERM2 6 5  4.50e-4
CTHERM3 5 4  5.10e-3
CTHERM4 4 3  7.50e-3
CTHERM5 3 2  1.20e-2
CTHERM6 2 TL 3.84e-2
RTHERM1 TH 6 4.00e-4
RTHERM2 6 5  6.00e-3
RTHERM3 5 4  3.00e-2
RTHERM4 4 3  5.60e-2
RTHERM5 3 2  9.60e-2
RTHERM6 2 TL 2.42e-1
*
.ENDS FGB40N60SM_Thermal
**----------------------------------------------------------------------------------
** Creation: Jan.-08-2016   Rev.: 2.0
** Fairchild Semiconductor